  PK
      ].N†–è  è  "   20xSM22forCosV5JuneMorphoRecon.ijm//Macro to identify overlaps in 3 channel images, and output the positive cells as a new channel.
//requires MorphoLibJ plugin from IJPB-plugins
//Dale Moulding and Carlotta Camilli June 2016
//Standard thresholding
 macro "SM22 20x analysis"{
 	
run("Colors...", "foreground=black background=white selection=yellow");
  
  dir1 = getDirectory("Input folder: images at any magnification from a single microscope"); //select an input folder
  dir2 = getDirectory("Choose a folder to save to"); //select an output folder. 
  list = getFileList(dir1); //make a list of the filenames
  setBatchMode(true); 

for (i=0; i<list.length; i++) {
 	showProgress(i+1, list.length);
 	filename = dir1 + list[i];
 	if (endsWith(filename, "tif")||endsWith(filename, "lsm")) {
open(filename);	
Imagename = File.nameWithoutExtension;

filename=getTitle();
run("Duplicate...", "title=Copy duplicate");
selectWindow(filename);
run("Subtract Background...", "rolling=20 stack");
run("Split Channels");
selectWindow("C1-"+filename);//process the dapi channel and identify nuclei
run("Median...", "radius=2");
setAutoThreshold("Li dark");
setOption("BlackBackground", false);
run("Convert to Mask");
run("Watershed");
run("Analyze Particles...", "size=10-Infinity show=Masks include summarize");
rename("DapiMask");
run("Duplicate...", "title=DapiMaskCopy duplicate");// makes a new window called "DapiMask & DapimaskCopy" the dapi channel
selectWindow("C2-"+filename);//process the green channel and identify +ve cytoplasm
run("Median...", "radius=1");
setAutoThreshold("Default dark");
setOption("BlackBackground", false);
run("Convert to Mask");
run("Dilate"); 
run("Close-"); 
run("Watershed"); //join up closely stained parts of a cell, then run a watershed to divide into cells.
run("Analyze Particles...", "size=10-Infinity show=Masks include summarize");
rename("CytoplasmMask");// makes a new window called "CytoplasmMask" the green cytoplasm channel
run("Duplicate...", "title=CytoplasmMaskCopy duplicate");
selectWindow("C3-"+filename);
run("Median...", "radius=2");
setAutoThreshold("Li dark");
setOption("BlackBackground", false);
run("Convert to Mask");
run("Watershed");
run("Analyze Particles...", "size=5-Infinity show=Masks include summarize");
rename("RedNucMask");// makes a new window called "RedNucMask" the green cytoplasm channel
run("Duplicate...", "title=RedNucMask duplicate");

// make a new window of the overlap between green cytoplasm and red nuclei called "Result of Mask of C2-filename"
run("Morphological Reconstruction", "marker=CytoplasmMask mask=RedNucMask type=[By Dilation] connectivity=4"); // makes an image of Red Nuceli that are ki67 +ve
rename("RedNucinGreencells");


run("Analyze Particles...", "size=5-Infinity show=Nothing include summarize"); 
run("Duplicate...", "title=RedNucInGreenCells2 duplicate"); // end of section counting red nuclei in green cells.

selectWindow("Copy");
run("Split Channels");
run("Merge Channels...", "c1=C1-Copy c2=C2-Copy c3=C3-Copy c4=DapiMask c5=CytoplasmMask c6=RedNucMask c7=[RedNucInGreenCells2] create");
selectWindow("Copy");
Stack.setChannel(1); //choose the colour of the first channel:
          run("Blue");
          Stack.setChannel(2); //choose the colour of the second channel:
          run("Green");
          Stack.setChannel(3); //choose the colour of the third channel:
          run("Red");
          Stack.setChannel(4); //choose the colour of the identified Red Nuclei channel:
          run("Grays");
          Stack.setChannel(5); //choose the colour of the masked Dapi channel:
          run("Cyan");
          Stack.setChannel(6); //choose the colour of the maksed green channel:
          run("Magenta");
          Stack.setChannel(7); //choose the colour of the masked red nuclei channel:
          run("Yellow");
selectWindow("Copy");
saveAs("Tiff", dir2+Imagename+"-masks&RedNucinGreenCells");//saves an image of the original plus masked Dapi, Green, Red Nuclei and Red nuclei in Green cells.

//this section selects Dapi nuclei that aren't red, then makes a new count and image of these non Red Dapi cells that are +ve for green cytoplasm

run("Morphological Reconstruction", "marker=RedNucMask mask=DapiMaskCopy type=[By Dilation] connectivity=4");
rename("Dapi&RedDualLabel");
imageCalculator("XOR create", "Dapi&RedDualLabel","DapiMaskCopy");
rename("DapiWithoutRed");
run("Morphological Reconstruction", "marker=CytoplasmMaskCopy mask=DapiWithoutRed type=[By Dilation] connectivity=4");
rename("DapiOnlyinGreenCells");

run("Analyze Particles...", "size=0-Infinity show=Nothing include summarize"); 

open(dir1+filename);
rename("OrigImage");	
run("Split Channels");
run("Merge Channels...", "c1=C1-OrigImage c2=C2-OrigImage c3=C3-OrigImage c4=DapiWithoutRed c5=DapiOnlyinGreenCells create");
Stack.setChannel(1); //choose the colour of the first channel:
          run("Blue");
          Stack.setChannel(2); //choose the colour of the second channel:
          run("Green");
          Stack.setChannel(3); //choose the colour of the third channel:
          run("Red");
          Stack.setChannel(4); //choose the colour of the identified Red Nuclei channel:
          run("Cyan");
          Stack.setChannel(5); //choose the colour of the masked Dapi channel:
          run("Grays");
saveAs("Tiff", dir2+Imagename+"+DapiOnlyinGreenCells");//saves an image of the nuclei that only have Dapi as Ch4 and inside green cells as Ch5.
run("Close All");
roiManager("Reset");
selectWindow("Summary"); saveAs("Results", dir2+Imagename+"-summary.csv");
run("Close");
 	}
}

exit("Macro finished "+i+" images processed");
 }PK? 
      ].N†–è  è  " $               20xSM22forCosV5JuneMorphoRecon.ijm
         À”þ«ÔòÙ±µþ«ÔÐÃÏÓPK      t   (    